Poor Mans Vario

BETA versie PMV code Juli 2014, (Deadband, hele meters & negatieve hoogte)

Voor wie het leuk vindt om wat nieuwe functies uit te proberen heb ik een tweetal features toegevoegd aan de PMV code.

1) Hoogte in hele meters als je lager bent dan 100 meter. Dit is eigenlijk bedoeld voor de DLG versie om de werphoogte op hele meters te kunnen laten afroepen, maar het zit als optie (customizable variable) in de code. Je moet dus voordat je de code in je Arduino stopt even kiezen welke regel je als commentaar "//" laat staan en bij welke regel je het commentaar vlaggetje "//" weghaalt.

2) Deadband dit is een waarde die je in kunt vullen ergens tussen 0 en 200 verwacht ik. Als je "0" invult dan werkt de vario zoals hij nu werkt en geeft constant een pieptoon. Met de komst van de SRX882 ontvanger is het echter mogelijk geworden om stilte te krijgen i.p.v. een harde ruis, bij geen audio signaal. Vul je een getal hoger dan "0" in bij "deadband", dan zal de vario stil zijn tot een bepaalde grenswaarde wordt overschreden vwb stijg- of daalsnelheid. Wat een beetje goede deadband waarde is heb ik nog geen flauw idee van, want ik heb er nog niet mee gevlogen. Ik begin eens ergens tussen de 50 en de 100 denk ik om uit te proberen. Dit kan ook een persoonlijke keuze zijn voor iedereen. 2e alternatief is dat je de deadband d.m.v. een opgesoldeerde potmeter instelbaar maakt op de vario zelf. Deze 10K potmeter soldeer je dan tussen de gaten 12, A1 (rocker) en A2.
P1100891.jpg


P1100893.jpg



3) Ik had er nooit aan gedacht als platlander, maar voor wie in de bergen vliegt en zijn zwever van de berg af kiepert, die wil natuurlijk ook zijn negatieve hoogte weten. Daar kan deze versie nu mee overweg.

Veel plezier met deze BETA versie (alleen voor BMP180).

Code: 
//**********************************
//*   BMP085 and BMP180 version    *
//**********************************
// This is the Poor Mans Vario code for the cheaper BMP085 and the BMP180 sensor by BOSCH Sensortec
// Arduino <> Sensor: Connect VCC to VCC and GND to GND, SCL goes to analogue pin 5, SDA to analogue pin4.
// Servo signal input, connect to Arduino pin D3
// Audio output to transmitter on pin D2
// All code by Rolf R Bakke, Oct 2012
// Modified by Hans Meijdam, June 2013: added altitude feature
// Modified by Hans Meijdam, November 2013: Sensor routine created for BMP085 and BMP180.
// Modified by Hans Meijdam, July 2014: BETA Version
// - Switch to select if whole meters are called out if below 100 meters altitude
// - Deadband to make vario silent if no certain climb or sink level is achieved
// - Negative altitude becomes now indicated as if it was positive altitude
//
//
//  ****** This is a customizable variable that acts as a switch *****
// choose "1" if you also want to hear the altitude in meters if you fly below 100 meters.
// choose "0" if you only want to hear the 10 meters rounded altitude at all times.
// Default is 0.
const byte altitude_per_meter = 0; // only altitude in 10 meters
//const byte altitude_per_meter = 1; // altitude in whole meters if below 100 meters


//  ****** This is a customizable variable (0 - 500 range) that defines how large the dead band is ******
// A dead band of "0" (= default) means that the vario will beep constantly, even with no climb or sink at all.
// A small dead band (e.g. value 25 - 50) means that with a small amount of climb or sink the vario will start beeping
// A medium dead band (e.g. value 50 - 100) means that the vario will be silent, unless it observes a medium rate of climb or medium rate of sink.
// A high dead band (> 100) makes the vario only active at high rates of sink or climb. 
int deadband = 0;  // no deadband or deadband defined by potmeter
// int deadband = 25;  // small deadband
// int deadband = 75;  // medium deadband
// int deadband = 150;  // large deadband

//  ****** Alternatively the deadband can be dynamically set by connecting a 10K potmeter over pins 12, A1 (rocker) and A2 ******
// const byte deadbandpotmeter = 0;  // no deadband potmeter present
const char deadbandpotmeter = 1;  // deadband potmeter is present (10K potmeter over pins 12, A1 (rocker) and A2)

#include "Wire.h"
const byte led = 13;
unsigned long time = 0;
float toneFreq, toneFreqLowpass, flpressure, lowpassFast, lowpassSlow ;
float p0; // this will be used to store the airfield elevation pressure
int altitude;
int ch1; // Here's where we'll keep our channel values
int ddsAcc;
#define I2C_ADDRESS 0x77
const unsigned char oversampling_setting = 3; //oversamplig for measurement
const unsigned char pressure_waittime[4] = { 
  5, 8, 14, 26 };
//Sensor parameters taken from the BMP085 datasheet
int ac1, ac2, ac3;
unsigned int ac4, ac5, ac6;
int b1, b2, mb, mc, md;
int temperature;
long pressure;
int analogpin1 = 0;

void setup()
{
  pinMode(A2, OUTPUT); // Prepare for high end of potmeter
  pinMode(12, OUTPUT); // Prepare for low end of potmeter
  pinMode(A1, INPUT_PULLUP); // Prepare for potmeter input
  digitalWrite(A2, HIGH); // High end potmeter to 5 volt
  digitalWrite(12, LOW); //Low end potmeter to 0 volt
  Serial.begin(9600); // start serial for output
  analogpin1 = analogRead(1);    // read the input pin A1 potmeter value
  Serial.print("Analog pin A0 value: ");
  Serial.println(analogpin1);
  Serial.println("Setting up BMP085");
  Wire.begin();
  bmp085_get_cal_data();
  bmp085_read_temperature_and_pressure(&temperature,&pressure);
  flpressure=pressure;// move long type pressure into float type flpressure
  p0 = lowpassFast = lowpassSlow = flpressure;
  Serial.print(" p0 = ");
  Serial.println(p0);
  pinMode(3, INPUT); // Set our input pins as such for altitude command input from receiver via pin D3
}

void loop()
{
  bmp085_read_temperature_and_pressure(&temperature,&pressure);
  // Serial.print(temperature,DEC);
  // Serial.print(" ");
  // Serial.print(pressure,DEC);
  // Serial.print(" ");
  flpressure = pressure;// move long type pressure into float type flpressure
  altitude = (float)44330 * (1 - pow(((float) flpressure/p0), 0.190295));
  //Serial.print(" ");
  //Serial.println(altitude);
  altitude = abs(altitude); // if flying from hills negative altitude becomes indicated as positive
  lowpassFast = lowpassFast + (flpressure - lowpassFast) * 0.2;
  lowpassSlow = lowpassSlow + (flpressure - lowpassSlow) * 0.1;
  toneFreq = (lowpassSlow - lowpassFast) * 50;
  toneFreqLowpass = toneFreqLowpass + (toneFreq - toneFreqLowpass) * 0.1;
  toneFreq = constrain(toneFreqLowpass, -500, 500);
  ddsAcc += toneFreq * 100 + 2000;

  if (deadbandpotmeter == 1)
  {
    analogpin1 = analogRead(1);    // read the input pin A1 potmeter value
    deadband = map(analogpin1, 0, 1024, 500, 0); // map potmeter value to deadband range from 500 - 0
  }

  if (toneFreq < 0 || ddsAcc > 0) 
  {
    if (abs(toneFreq)>deadband)
    {
      tone(2, toneFreq + 550);  
      ledOn();  // the Arduino led will blink if the Vario plays a tone, so you can test without having audio connected
    }
  }
  else
  {
    noTone(2);
    ledOff();
  }
  while (millis() < time);        //loop frequency timer
  time += 20;
  int ones = altitude%10;
  int tens = (altitude/10)%10;
  int hundreds = (altitude/100)%10;
  int thousands = (altitude/1000)%10;
  //   Serial.print ("thousands: ");
  //   Serial.println   (thousands);    
  //   Serial.print ("hundreds:  ");
  //   Serial.println   (hundreds);  
  //   Serial.print ("tens:      ");
  //   Serial.println   (tens);  
  //   Serial.print ("ones:      ");
  //   Serial.println   (ones);    
  ch1 = pulseIn(3, HIGH, 25000); // Read the pulse width of servo signal connected to pin D3
  //  Serial.print (ch1);
  //
  //   if(ch1>1000){
  //    Serial.println("Left Switch: Engaged");
  //   } 
  //   if(ch1<1000){
  //     Serial.println("Left Switch: Disengaged");
  //   }
  if((map(ch1, 1000,2000,-500,500)) > 0) // interpret the servo channel pulse, if the Vario should beep altitude or send vario sound 
  {
    noTone(2); // create 750 ms of silence, or you won't hear the first altitude beep
    ledOff();
    delay(750);

    if(hundreds == 0)
    {
      tone(2,900);                //long duration tone if the number is zero
      ledOn();
      delay(600);
      noTone(2);
      ledOff();
    }
    else
      for(char a = 0; a < hundreds; a++)          //this loop makes a beep for each hundred meters altitude
      {
        tone(2,900); // 900 Hz tone frequency for the hundreds
        ledOn();
        delay(200);
        noTone(2);
        ledOff();
        delay(200);
      }
    delay(750);                            //longer delay between hundreds and tens

    if(tens == 0)
    {
      tone(2,1100);                //long pulse if the number is zero
      ledOn();
      delay(600);
      noTone(2);
      ledOff();
    }
    else
      for(char a = 0; a < tens; a++)          //this loop makes a beep for each ten meters altitude
      {
        tone(2,1100); //1100 Hz tone frequency for the tens
        ledOn();
        delay(200);
        noTone(2);
        ledOff();
        delay(200);
      }

    if (altitude_per_meter == 1 && hundreds == 0)
    {
      delay(750);                            //longer delay between tens and ones

      if(ones == 0)
      {
        tone(2,1300);                //long pulse if the number is zero
        ledOn();
        delay(600);
        noTone(2);
        ledOff();
      }
      else
        for(char a = 0; a < ones; a++)          //this loop makes a beep for each meter altitude
        {
          tone(2,1300); //1300 Hz tone frequency for the ones
          ledOn();
          delay(200);
          noTone(2);
          ledOff();
          delay(200);
        }
    }  
  } 
}

void bmp085_read_temperature_and_pressure(int* temperature, long* pressure) {
  int ut= bmp085_read_ut();
  long up = bmp085_read_up();
  long x1, x2, x3, b3, b5, b6, p;
  unsigned long b4, b7;

  //calculate the temperature
  x1 = ((long)ut - ac6) * ac5 >> 15;
  x2 = ((long) mc << 11) / (x1 + md);
  b5 = x1 + x2;
  *temperature = (b5 + 8) >> 4;

  //calculate the pressure
  b6 = b5 - 4000;
  x1 = (b2 * (b6 * b6 >> 12)) >> 11;
  x2 = ac2 * b6 >> 11;
  x3 = x1 + x2;

  if (oversampling_setting == 3) b3 = ((int32_t) ac1 * 4 + x3 + 2) << 1;
  if (oversampling_setting == 2) b3 = ((int32_t) ac1 * 4 + x3 + 2);
  if (oversampling_setting == 1) b3 = ((int32_t) ac1 * 4 + x3 + 2) >> 1;
  if (oversampling_setting == 0) b3 = ((int32_t) ac1 * 4 + x3 + 2) >> 2;

  x1 = ac3 * b6 >> 13;
  x2 = (b1 * (b6 * b6 >> 12)) >> 16;
  x3 = ((x1 + x2) + 2) >> 2;
  b4 = (ac4 * (uint32_t) (x3 + 32768)) >> 15;
  b7 = ((uint32_t) up - b3) * (50000 >> oversampling_setting);
  p = b7 < 0x80000000 ? (b7 * 2) / b4 : (b7 / b4) * 2;

  x1 = (p >> 8) * (p >> 8);
  x1 = (x1 * 3038) >> 16;
  x2 = (-7357 * p) >> 16;
  *pressure = p + ((x1 + x2 + 3791) >> 4);
}

unsigned int bmp085_read_ut() {
  write_register(0xf4,0x2e);
  delay(5); //longer than 4.5 ms
  return read_int_register(0xf6);
}

void bmp085_get_cal_data() {
  Serial.println("Reading Calibration Data");
  ac1 = read_int_register(0xAA);
  Serial.print("AC1: ");
  Serial.println(ac1,DEC);
  ac2 = read_int_register(0xAC);
  Serial.print("AC2: ");
  Serial.println(ac2,DEC);
  ac3 = read_int_register(0xAE);
  Serial.print("AC3: ");
  Serial.println(ac3,DEC);
  ac4 = read_int_register(0xB0);
  Serial.print("AC4: ");
  Serial.println(ac4,DEC);
  ac5 = read_int_register(0xB2);
  Serial.print("AC5: ");
  Serial.println(ac5,DEC);
  ac6 = read_int_register(0xB4);
  Serial.print("AC6: ");
  Serial.println(ac6,DEC);
  b1 = read_int_register(0xB6);
  Serial.print("B1: ");
  Serial.println(b1,DEC);
  b2 = read_int_register(0xB8);
  Serial.print("B2: ");
  Serial.println(b2,DEC);
  mb = read_int_register(0xBA);
  Serial.print("MB: ");
  Serial.println(mb,DEC);
  mc = read_int_register(0xBC);
  Serial.print("MC: ");
  Serial.println(mc,DEC);
  md = read_int_register(0xBE);
  Serial.print("MD: ");
  Serial.println(md,DEC);
}

long bmp085_read_up() {
  write_register(0xf4,0x34+(oversampling_setting<<6));
  delay(pressure_waittime[oversampling_setting]);

  unsigned char msb, lsb, xlsb;
  Wire.beginTransmission(I2C_ADDRESS);
  Wire.write(0xf6); // register to read
  Wire.endTransmission();

  Wire.requestFrom(I2C_ADDRESS, 3); // read a byte
  while(!Wire.available()) {
    // waiting
  }
  msb = Wire.read();
  while(!Wire.available()) {
    // waiting
  }
  lsb |= Wire.read();
  while(!Wire.available()) {
    // waiting
  }
  xlsb |= Wire.read();
  return (((long)msb<<16) | ((long)lsb<<8) | ((long)xlsb)) >>(8-oversampling_setting);
}

void write_register(unsigned char r, unsigned char v)
{
  Wire.beginTransmission(I2C_ADDRESS);
  Wire.write(r);
  Wire.write(v);
  Wire.endTransmission();
}

char read_register(unsigned char r)
{
  unsigned char v;
  Wire.beginTransmission(I2C_ADDRESS);
  Wire.write(r); // register to read
  Wire.endTransmission();

  Wire.requestFrom(I2C_ADDRESS, 1); // read a byte
  while(!Wire.available()) {
    // waiting
  }
  v = Wire.read();
  return v;
}

int read_int_register(unsigned char r)
{
  unsigned char msb, lsb;
  Wire.beginTransmission(I2C_ADDRESS);
  Wire.write(r); // register to read
  Wire.endTransmission();

  Wire.requestFrom(I2C_ADDRESS, 2); // read a byte
  while(!Wire.available()) {
    // waiting
  }
  msb = Wire.read();
  while(!Wire.available()) {
    // waiting
  }
  lsb = Wire.read();
  return (((int)msb<<8) | ((int)lsb));
}


void ledOn()
{
  digitalWrite(led,1);
}


void ledOff()
{
  digitalWrite(led,0);
}
 
Laatst bewerkt:
Vandaag de vario eindelijk uit kunnen testen. Hij lag al even op de werkbank. De ontvanger in een servodoosje gebouwd. Naast mn stoel gezet op het veld en lekker zweven. Helemaal blij ermee!!
 
Discus2ct zei:
Leuk hoor. En een eventueel setje is ook compleet met de laatste firmware en deadband potmeter?
Klik om te vergroten...
Ja hoor, dat gaat gewoon in overleg met de belangstellende. Doordat ik nu wat extra parameters in de software bouw, kan ik op het moment van het programmeren van de vario de gewenste opties activeren/deactiveren.

Op mijn wensenlijstje staan ook nog:
- batterijbewaking dmv audio signaal
- instelbare vario gevoeligheid
- maximale hoogte afroepbaar
 
Aan de slag met het bouwpakket

Dag Hans, en alle andere lezers,

Ook ik ben vrijdag begonnen met het in elkaar solderen van de Poor Man´s Vario.
En dat onder toeziend oog van één van onze jeugdleden.....
Heel leuk en dankzij de uitgeprinte handleiding prima te doen!

Voorlopig zit de ontvanger in elkaar. Enige probleem in de handleiding is dat er niet staat hoe je de pinheaders erop moet solderen. Als electronica-leek vertrouw ik op de foto´s, en daarop lijkt het, dat de korte kant naar boven steekt. Dat blijkt dus fout te zijn, want nu blijven de stekkers er niet op zitten.
Jammer, maar dan soldeer ik de bedrading van de batterij-pak en de speaker wel rechtstreeks op de pinnetjes.

Verder kan Hans blijkbaar goed "spoortjes koeken", bij mij liep dat al gauw uit de hand. Ik heb een klein stroomdraadje genomen, steeds 5 cm kaal gehaald, en vertind. Dit gebruikt als verbindingsbrug. Dat werkte een stuk preciezer. De bochten maakte ik door een paperclip in het gaatje waar de bocht moest komen te zetten en het draadje hieromheen te buigen.
Al met al heel goed te doen.

Ik had graag een foto toegevoegd, maar de handleiding hiervoor van MBF snap ik dan weer niet.......geen plaatjes........
Een volgende keer maar.....

Groeten,
Eric Velthuizen
te Soest
 
Otto's Eric zei:
Enige probleem in de handleiding is dat er niet staat hoe je de pinheaders erop moet solderen. Als electronica-leek vertrouw ik op de foto´s, en daarop lijkt het, dat de korte kant naar boven steekt. Dat blijkt dus fout te zijn, want nu blijven de stekkers er niet op zitten.
Klik om te vergroten...
Bedankt voor de feedback!
Dat had ik zelf nooit verzonnen dat zoiets fout kon gaan dus ik heb de handleiding aangepast.

Die pinheaders kun je stuk voor stuk lossolderen door ze met de soldeerbout warm te stoken en er tegelijkertijd met een tangetje aan te trekken. Dan komt het pinnetje los uit het soldeer en ook uit het plastic.

De truuk van de klodderspoortjes is om eerst een rij klodders neer te leggen en dan de er tussenin nog een klodder. Die "tussenin klodder" moet je eerst aan je soldeerbout hangen en dan heel snel tussen twee bestaande klodders neerleggen. Anders smelten de twee klodders die er al leggen weer en zakken ze door de gaatjes heen naar de andere kant van de print. Ik vind dit ook zelf het lastigste stuk van de bouw.
Gefeliciteerd dat het allemaal is gelukt.
 
Dag Hans,

Helaas moet ik melden dat mijn systeem niet werkt. Eerst dacht ik dat het aan de schakelaar lag. Met wat moeite heb ik een andere erin gesoldeerd.
Maar ik krijg zelfs geen ruis uit de luidspreker of oortjes.

Kun je mij helpen de oorzaak te achter halen?
Graag kom ik een keer bij je langs.

Groeten,
Eric
 
Zo, dit draadje een paar keer doorgelezen en ook geïnfecteerd vrees ik :p

Echter gezien het met 21 pagina's en diverse uitvoeringen wellicht niet helemaal 100% bij mij binnenkomt even een kleine samenvatting zoals ik het zie (en zodat ik de juiste spullen koop:

Ik kan kiezen tussen een 3,3V Arduino Pro Mini maar als ik zo'n Pro mini o.d. neem dan moet ik nog wel een USB => TTL verbinding erbij hebben zoals bijv. HIER want anders krijg ik niets in die Arduino.

Indien ik op 3,3V blijf kan ik er direct een Bosch BMP180 druksensor op monteren gezien de spanning voor beiden dan 3,3V bedraagt.
Indien ik de iets nauwkeuriger edoch wellicht te nerveuze MS5611 sensor benut hoef ik niet zozeer op de spanning te letten INDIEN deze MS5611 is voorzien van een voltage regulator.
In het geval deze hier niet over beschikt geldt hetzelfde als bij de BMP180 (3,3V).

Enkel moet ik dan nog wel iets doen om de ingaande spanning ook op 3,3V te brengen omdat anders alsnog de hele mikmak in rook opgaat.

In het geval dat ik bijv. een Arduino Nano of UNO op 5V neem dan heb ik normaliter gelijk die USB aansluiting maar dan kan ik die BMP180 niet toepassen. De MS5611 met regulator wel.
Zoals ik het nu zie kan ik de voeding in dit geval direct van de BEC/Ontvanger halen mits deze op 5,0V is afgeregeld.

Voor het zenden en ontvangen zou dan zo'n setje van HK volstaan.
Voedingsspanning is niet zo van belang (ik bedoel hiermee niet specifiek 3,3V of 5,0V).

Daarbij heb ik dan zo'n simpel speakertje (bijv. diegene die jij aangaf van de Conrad) nodig om het geluid eruit te krijgen.
En een LM386 miniversterker.

Mijn resterende vragen:
* LM386, moet dat een specifiek model zijn of volstaat iets zoals DEZE?

* Kun je nog iets specifieker zijn in het omzetten van de 5,0V BEC / ontvangerspanning naar 3,3V voor de Arduino? Ik ben niet helemaal mee met die weerstanden in de voedingskabel.

* Is er een mogelijkheid om een BMP 180 3,3V op een 5,0V Arduino te plaatsen, of beter gezegd hoe?

Het gewicht van de Vario vind ik zelf niet zo heel erg belangrijk. (Ik vlieg geen DLG's).
Het kan best zijn dat de/sommige antwoorden op deze vragen ergens in de voorgaande 21 pagina's al de revue zijn gepasseerd, in dat geval mijn excuses voor het alsnog vragen.
 
Ik gebruik een arduino pro micro 5v en heb om de sensor te voeden een weerstand van 1k en een zenerdiode gebruikt. Werkt gewoon super geen enkel probleem. En de kostprijs is het ook niet 0.45 eurocent
 
Hallo Dutchy,

Zowel de Pro Mini als de BMP180 sensor module hebben een voltregelaar aan boord. De BMP180 module kun je dus direct aansluiten op de 5volt Pro Mini. Je hebt wel inderdaad de USB>TTL converter nodig.
De Arduino Nano werkt prima samen met de BMP180 sensor. Dan heb je USB aan boord van de arduino.

Zender setje van HK is een goed setje, dat ik tot voor kort met succes gebruikte. Echter de bouwpakketten die ik pas heb samengesteld, alsmede de bouwpakketen in voor augustus krijgen de STX882 en SRX882 zender/ontvanger module. Daar is ook de print layout op gebaseerd.

De LM386 module waarnaar je verwijst zou ik niet nemen. Ik heb hem pas ook gekocht uit nieuwsgierigheid en degene die ik kreeg was een microfoonversterker van 200x. Je hebt een 20x versterkertje nodig. Die dien je zelf te solderen op basis van alleen de LM386 chip, één condensator, potmeter en één weerstand.

Lees de handleiding van de ontvanger nog eens door in dit draadje en daarin vind je ook het schema.
Alternatief is dat je je opgeeft voor een bouwpakketje (gepland voor augustus) met alle onderdelen, of desnoods een short-kit voor alleen de ontvanger + zendmodule. Als je je Vario nl zelf programmeert kun je de software nog helemaal naar je eigen wens veranderen.

succes
Hans
 
Hallo Hans en Buikje,

Bedankt voor de reacties.
Handig om te weten dat je een 5V board ook gewoon met "elke" BMP180 gebruiken. Dat maakt de spoeling alweer een stuk groter.
De informatie op Ebay is vaak een beetje een gok. Veelal staat er enkel 1,8-3,6V, bij anderen staat er weer voorbereid op 3,3 - 5V en dan zijn er ook nog de Adafruits van 5x zo duur.
Een beetje basiskennis van elektronica heb ik wel maar niet echt in deze hoek.
Ik ga er dan ook vanuit dat een Adafruit of zo'n 3,3-5,0V versie degene is die ik uiteindelijk moet hebben?

Die STX/SRX setjes had ik ook al gezien. Enkel waren dat setjes met zo'n spoelantenne?
Maar ik neem aan dat je die ook gewoon kunt vervangen door een passende antennedraad.

Maar dan heb ik dus al een Nano-board, de BMP180, de zender ontvanger is ook duidelijk, enkel nog even kijken naar die versterker en een speaker.
Daarnaast nog eens door de voorgaande 21 pagina's spitten maar het is me in ieder geval een stuk duidelijker.

De optie om zo'n samengesteld kitje bij jou te halen hou ik even in mijn achterhoofd.
Als ik diverse zaken bij diverse Ebay-leveranciers vandaan moet halen zal het ook niet echt veel sneller hier zijn denk ik.
 
_Dutchy_ zei:
Die STX/SRX setjes had ik ook al gezien. Enkel waren dat setjes met zo'n spoelantenne?
Maar ik neem aan dat je die ook gewoon kunt vervangen door een passende antennedraad.
Klik om te vergroten...
Klopt. Ik vind een draadje wat makkelijker wegwerken in een model. Maar ik heb ook wel eens het spoeltje gebruikt hoor. Dan doe ik er wel een stukje stuurkabelmantel in en een krimpkous omheen, om de spoel te fixeren. Qua prestatie heb ik geen verschil kunnen ontdekken.
 
...... en hier weer een bewijs dat je met een klein beetje soldeerkunst en goed kunnen lezen, de vario in elkaar kunt zetten.

Nu nog testen in het eggie.. ;-)

full
 
Laatst bewerkt door een moderator:
hmeijdam zei:
Dat extra boardje is een foto van de onderkant
Klik om te vergroten...

Ja zegt die ?! :oops:

:hammer:
Mea Culpa, bedtijd denk ik.

Ik zie wel in de beschrijving dat bij die ene met die extra foto een Bootloader present is in tegenstelling tot die andere.


Is het trouwens ook zo dat de ingangsspanning naar de Arduino toch niet zo heel belangrijk is?
Operating Voltage 5V
Input Voltage (recommended) 7V-12V
Input Voltage (limits) 6V-20V
Klik om te vergroten...
 
Je moet er wel een met bootloader nemen, anders heb je een andere Arduino nodig, een bepaald programma en acht draadjes om er eerst een bootloader op te programmeren. Dat kan niet via USB.
 
You must log in or register to reply here.
Back
Top